2 Построение графиков функций и начала анализа

Построение графиков - функция wxplot2d

Построение графика функции одной переменной: 
(%i1) wxplot2d( sin(x), [x,-%pi,%pi], [y,-1,1]);

Первый параметр - sin(x) функция, график которой необходимо постоить, второй параметр [x,-%pi,%pi] - аргумент функции и область определения функции, третий параметр [y,-1,1] задает область значений функции, которая будет отображаться на графике.

Для построения нескольких графиков на одном рисунке необходимо задать функции в виде списка:

(%i2) wxplot2d([sin(x),cos(x)], [x,-3,3], [y,-1,1]);
Пример параметрического построения окружности:
(%i3) wxplot2d([[parametric, cos(t), sin(t), [t, 0, 2*%pi], [nticks, 300]]], [x,-1,1]);
Здесь окружность задается следующим списком:  [parametric, cos(t), sin(t), [t, 0, 2*%pi], [nticks, 300]]], где cos(t) - функция x(t), sin(t) - функция y(t),  [t, 0, 2*%pi] - параметр и область его определения, [nticks, 300] - количество точек в построении.

2 Построение графиков - функция draw2d

Для использования этой функции нужно дать команду load(draw).
Построение простой (явной) функции при помощи draw2d:
(%i4) draw2d(nticks=300, explicit(sin(x),x,-%pi,%pi));
Здесь функция f(x)=sin(x) конструируется при помощи вызова explicit(sin(x),x,-%pi,%pi).

Построение неявной функции (окружности):
(%i5) draw2d(nticks=300, implicit(x^2+y^2=1,x,-1,1,y,-1,1));
Использование функции draw2d для построения графика функции в полярных координатах:
(%i6) draw2d(nticks=300, polar(t,t,0,4*%pi));
Здесь функция задается, как функция радиуса r(t). Функция конструируется в виде вызова polar(t,t,0,4*%pi), у которой первый параметр - это функция r(t), второй параметр - это обозначение полярного угла t, далее границы области определения угла.

Построение графиков функции 2 переменных

(%i7) plot3d(sin(x)*sin(y), [x,-5,5], [y,-5,5], [plot_format,gnuplot]);

Вычисление пределов

Предел функции sin(x) в точке x=0.
(%i8) limit(sin(x)/x,x,0);
(%o8) 1
В качестве пределов можно использовать и бесконечности:
(%i9) limit( (1+1/n)^n,n,inf);
(%o9) %e
Для вычисления левых и правых пределов функции необходимо передать еще один дополнительных параметр: minus или plus:
(%i10) limit(abs(x)/x,x,0,plus);
(%o10) 1
(%i11) limit(abs(x)/x,x,0,minus);
(%o11) -1

Вычисление сумм и произведений

Для вычисления конечных и бесконечных сумм используется функция sum:
Пример вычисления суммы всех натуральных чисел от 1 до 100 и суммы их квадратов:
(%i12) sum(k,k,1,100);
(%o12) 5050
(%i13) sum(k^2,k,1,100);
(%o13) 338350

Пример вычисления бесконечных сумм, с использованием функции simplify_sum для упрощения результата:
(%i14) sum(1/2^i,i,0,inf);
                                   inf
                                   ====
                                   \     1
(%o14)                              >    --
                                   /      i
                                   ====  2
                                   i = 0
(%i15) load(simplify_sum);
(%i16) simplify_sum(%o14);
(%o16) 2
Произведения можно вычислять при помощи функции product, ее синтаксис аналогичен функции sum:
(%i17) product(i,i,1,6)
(%o17) 720

Упражнения

Загрузить условия задания 2